****************************************************************
*                                                              *
* PROGRAM:      CII.SAS                                        *
*                                                              *
* PROGRAMMER:   Unknown (original not commented)               *
*                                                              *
* PURPOSE:      Create a SAS dataset containing derived        *
*               variables of the Coder Impressions Inventory   *
*               (CII) and CII Addendum.                        *
*                                                              *
* MODIFIED:     11/27/01 Patrick Malone to run off aggregated  *
*               datasets.                                      *
*				6/23/04 J. Godwin to use linmean macro		   *
*				1/23/06 cii&yr.non changed to recoded item 1
****************************************************************;

**Fill out information in next section for data processed **
**in this run.                      **;

     %let source=Observer;
	 %let src=o;
	 %let inst=g;
	 %let longname=coderimpressionsinventory;
	 %let scoredname=CII;

**Enter high-level path (e.g., l:\datasets) **;

	 %let path=n:\datasets;

**Enter year of data collection **;

     %let yr=3; 

**Enter variable which must be present to retain record (typically interviewer id) **;

	 %let screen=intid;

**Specify Lib for input datasets **;

     Libname SASIN "&path.\&source.\&longname.\U";
     libname addendum "&path.\&source.\coderimpressionsinventoryadd\U";

**Specify Lib for output datasets **;

     Libname SASOUT "&path.\&source.\&longname.\S";


****** DO NOT MODIFY BELOW THIS LINE **************;

%macro linmean;
data &INDATA;
   set &INDATA;
   label &var_name = "&var_labl";
   array sumvars {*} &var_list;
   if n(of sumvars(*))>=.5*dim(sumvars) then &var_name=mean(of sumvars(*));
proc sort; by site tcid;
run;
%mend linmean;

data one;
set SASIN.&src.&yr.&inst;
run;
proc sort; by site tcid;

data two;
set addendum.&src.&yr.h;
run;
proc sort;by site tcid;


data SASOUT.&scoredname.&yr.;
  merge one (in=in1) two (in=in2);
  by site tcid;

  ARRAY ORIG (*) o&yr.g6 o&yr.g7 o&yr.g13 o&yr.g21 o&yr.g40 o&yr.g41 o&yr.g45 o&yr.g52 o&yr.g53 o&yr.g55 o&yr.g56;
  ARRAY new (*) o&yr.g6r o&yr.g7r o&yr.g13r o&yr.g21r o&yr.g40r o&yr.g41r o&yr.g45r o&yr.g52r o&yr.g53r o&yr.g55r o&yr.g56r ;

  do i= 1 to dim(new);
  new(i)=4-orig(i);
  end;

  o&yr.g33r=100-o&yr.g33;

  o&yr.g1x=o&yr.g1/2;
  o&yr.g33rx=o&yr.g33r/33.34;
  o&yr.g34x=o&yr.g34/33.34;

label 
		o&yr.g13r="Reversed-TC Did Something Prosocial, P. Ignored"
		o&yr.g1x="Recoded-TC's Conduct During Observation Session"
		o&yr.g21r="Reversed-Parent D/N Pay Attention when TC Talked"
		o&yr.g33r="Reversed-Est. % Time Family was Misbehaving (M)"
		o&yr.g33rx="Recoded-Est. % Time Family was Misbehaving (M)"
		o&yr.g34x="Recoded-Est. % Time Family was Misbehaving (TC)       "
		o&yr.g40r="Reversed-Parent Overly Permissive, Laissez-Faire"
		o&yr.g41r="Reversed-Parent Erratic, Inconsistent, Haphazard"
		o&yr.g45r="Reversed-Seemed to Track Child Too Closely"
		o&yr.g52r="Reversed-Parent Relates to TC as a Peer"
		o&yr.g53r="Reversed-Parent Seemed Distant, Detached from TC"
		o&yr.g55r="Reversed-Child Treated Mother with Respect"
		o&yr.g56r="Reversed-TC Seemed Aloof, Detached from Mother"
		o&yr.g6r="Reversed-Parent Made Unreasonable Requests"
		o&yr.g7r="Reversed-Parent Used Guilt Induction"
;
drop i;
run;


    %let INDATA =SASOUT.&scoredname.&yr.;

    %let var_name = cii&yr.war;
    %let var_labl = %str(Y&yr. CII Parent Warmth) ;
    %let var_list = %str(	o&yr.g13r o&yr.g20 o&yr.g21r o&yr.g23 o&yr.g24 o&yr.g25 
							o&yr.g29 o&yr.g35 o&yr.g51 o&yr.g53r o&yr.h1 o&yr.h2)	 ;
    %linmean;

    %let var_name = cii&yr.app;
    %let var_labl = %str(Y&yr. CII Appropriate Discipline) ;
    %let var_list = %str(	o&yr.g6r o&yr.g7r o&yr.g8 o&yr.g15 o&yr.g19 o&yr.g33rx o&yr.g40r 
							o&yr.g41r o&yr.g45r o&yr.g58 o&yr.h3 o&yr.h4 o&yr.h5)	 ;
    %linmean;

    %let var_name = cii&yr.har;
    %let var_labl = %str(Y&yr. CII Harsh Discipline) ;
    %let var_list = %str(	o&yr.g4 o&yr.g17 o&yr.g18 o&yr.g39 o&yr.g46)	 ;
    %linmean;
	
    %let var_name = cii&yr.phy;
    %let var_labl = %str(Y&yr. CII Physical Discipline) ;
    %let var_list = %str(	o&yr.g31 o&yr.h6)	 ;
    %linmean;
	
    %let var_name = cii&yr.cwm;
    %let var_labl = %str(Y&yr. CII Child Warmth toward Parent) ;
    %let var_list = %str(	o&yr.g12 o&yr.g26 o&yr.g30 o&yr.g37 o&yr.g56r)	 ;
    %linmean;
    %let var_name = cii&yr.non;
    %let var_labl = %str(Y&yr. CII Child Noncompliance toward Parent) ;
    %let var_list = %str(	o&yr.g1x o&yr.g2 o&yr.g27b o&yr.g32 o&yr.g34x o&yr.g54 o&yr.g55r)	 ;
    %linmean;


proc sort ;
by cohort site tcid;  
run;